Arduino MKR 1500 taking too much time to connect

Please run the following script and enter the commands 0-8, a-e in the Serial Console sequentially after the previous command has finished.

Please note: commands "8" and "a" in particular usually take a while to run.

Then send the response you get to telstradev@team.telstra.com, as some of the data returned is semi-sensitive.

This will help us work out what part is not working (e.g. SIM, Hardware, Network, etc).

/*
   DebugATCommandsSARA sketch

   This sketch is modified from SerialSARAPassthrough.

   The sketch allows you to send 15 basic AT commands from the USB CDC serial port
   of the MKR NB 1500 board to the onboard ublox SARA-R410 celluar module.

   If you want to add more commands the list of supported AT commands are found here:
   https://www.u-blox.com/sites/default/files/u-blox-CEL_ATCommands_%28UBX-13002752%29.pdf

   Circuit:
   - MKR NB 1500 board
   - Antenna
   - 1500 mAh or higher lipo battery connected recommended
       - USB seems to have enough power (tested with my PC)
   - SIM card

   Make sure the Serial Monitor's line ending is set to "Both NL and CR"

   create 26 February 2019
   Tomi Sarajisto
*/

// baud rate used for both Serial ports
unsigned long baud = 115200;
char command;

void setup() {
  // enable the POW_ON pin
  pinMode(SARA_PWR_ON, OUTPUT);
  digitalWrite(SARA_PWR_ON, HIGH);
  
  // reset the ublox module
  pinMode(SARA_RESETN, OUTPUT);
  digitalWrite(SARA_RESETN, HIGH);
  delay(100);
  digitalWrite(SARA_RESETN, LOW);

  Serial.begin(baud);
  SerialSARA.begin(baud);
}

void loop() {
  if (Serial.available()) {
    command = Serial.read();
    switch (command)
    {
      case '0':
        Serial.println("m: Set verbose error resultcodes");
        SerialSARA.println("AT+CMEE=2");
        break;
      case '1':
        Serial.println("1: Check IMEI");
        SerialSARA.println("AT+GSN");
        break;
      case '2':
        Serial.println("2: Check IMSI");
        SerialSARA.println("AT+CIMI");
        break;
      case '3':
        Serial.println("3: Check RAT type config");
        SerialSARA.println("AT+URAT?");
        break;
      case '4':
        Serial.println("4: Check band configuration");
        SerialSARA.println("AT+UBANDMASK?");
        break;
      case '5':
        Serial.println("5: Check signal");
        SerialSARA.println("AT+CSQ");
        break;
      case '6':
        Serial.println("6: Check APN configuration");
        SerialSARA.println("AT+CGDCONT?");
        break;
      case '7':
        Serial.println("7: Check network");
        SerialSARA.println("AT+COPS?");
        break;
      case '8':
        Serial.println("8: Check all available networks (takes long time)");
        SerialSARA.println("AT+COPS=?");
        break;
      case 'a':
        Serial.println("a: Reset HTTP profile #0");
        SerialSARA.println("AT+UHTTP=0");
        break;
      case 'b':
        Serial.println("b: Set server domain name");
        SerialSARA.println("AT+UHTTP=0,1,\"jsonplaceholder.typicode.com\"");
        break;
      case 'c':
        Serial.println("c: Set to server port 80");
        SerialSARA.println("AT+UHTTP=0,5,80");
        break;
      case 'd':
        Serial.println("d: GET request");
        SerialSARA.println("AT+UHTTPC=0,1,\"/posts/1\",\"get.ffs\"");
        break;
      case 'e':
        Serial.println("e: Read response");
        SerialSARA.println("AT+URDFILE=\"get.ffs\"");
        break;

    }

  }

  if (SerialSARA.available()) {
    Serial.write(SerialSARA.read());
  }

}

Hi ZHENGLIN WANG,

The Arduino MKR NB 1500 boards sold on TelstraDev come with Cat-M1 only SIMs, so you will not get a successful connection if you select NB-IoT only as the RAT.

The UBLOX module and Arduino board itself IS compatible for NB-IoT but Telstra has officially certified this device for Cat-M1 only, so we only provide Cat-M1 as default.

Does your use case require NB-IoT specifically?

Absolutely, NB-IOT has a greater coverage area than CatM1 (about 4mill sq km vs 3.5mill) and is well suited to remote, stationary iot deployments. Agritech is a very common use case.

Please send me the details of your SIM card via email and I will get nb-iot activated for you. Please keep in mind that this device is not optimised for nb-iot and we are unable to guarantee support for this case as the device is not certified with Telstra on nb-iot. You may also need to perform a firmware upgrade but you will need to liaise with the u-blox modem support directly as this is not something Telstra can support